#!/bin/csh

#######################################################################
#This system takes a supervised learning approach to word sense
#disambiguation, where a decision tree is induced from sense-tagged
#training examples and then used to assign senses to the test examples. No
#information from WordNet is utilized by this system. 

#This system uses a filter to perform feature identification prior to
#learning. All bigrams (two word sequences) that meet the following
#criteria form a set of candidate features: 

#1) occur 2 or more times and 
#2) have a log-likelihood ratio >= to 6.635 (i.e., p=.01) and 
#3) are not made up of stop-listed words. 

#The training examples are converted into feature vectors, where each
#feature represents whether a candidate feature occurs in the context of a
#specific training example. 

#The feature vectors are the input to the J48 learning algorithm, the Weka
#implementation of the C4.5 decision tree learner. The parameter settings
#for pruning are C=0.25 (a confidence threshold) and M=2 (the number of
#training examples that must be covered by each leaf in the tree). 

#The decision tree learner is "bagged". The training examples are sampled
#ten times (with replacement) and a decision tree is learned for each
#sample. Each test example is assigned a sense based on a vote taken from
#among the learned trees. 

#This is based on the NAACL-01 paper "A Decision Tree of Bigrams is an
#Accurate Predictor of Word Sense" by Ted Pedersen. The use of bagging and
#a stop list is new for Senseval. 
#######################################################################


if ($#argv != 3) then
   echo "duluth2 source-dir stoplist token"
   echo 
   echo "source-dir : directory where data resides"
   echo "in this distribution source-dir is LexSample"
   echo 
   echo "stop-list: text file of stop words"
   echo "in this distribution stop-list is stop.list"
   echo 
   echo "token : text file of token definitions"
   echo "in this distribution token is token1.txt"
   echo 
   echo "run from directory where source-dir, stop-list, and token reside"
   echo
   echo "if you don't want to use stop.list and/or token just create"
   echo "a blank file via echo > dummy and use that instead"
   exit 1
endif   

# specify the name of your stop list and token definition file
# for some reason things work better if you specify the full
# path name of the stoplist and token files

set sourcedir=$1
set stoplist=$PWD/$2
set token=$PWD/$3

if !(-e $sourcedir) then 
	echo "$sourcedir sourcedir does not exit"
	exit 1
endif

if !(-e $stoplist) then 
	echo "$stoplist stoplist does not exit"
	exit 1
endif

if !(-e $token) then 
	echo "$token token does not exit"
	exit 1
endif

foreach method (f0)

	# the results for each method are contained in a directory,
	# which has the same name as the method

	if (-e $method) then
                echo $method already exists, aborting
                exit 1
        endif 

	mkdir $method

	# within each method directory, there is a directory for 
	# each word

	# step into source directory and find out the names of
	# all the files to be processed. Each file is named after
        # a word to be processed.

	cd $sourcedir
        set wordlist = (*)
	cd ..

	# now process each of those words

	foreach word ($wordlist)
        
		# move the text for a word into the appropriate directory

		cd $sourcedir
		cp -r $word ../$method
		cd ..
		cd $method/$word

		# now process that text with the desired method
		
		$method $word $stoplist $token

		# convert the text into a form that weka likes (arff)

		xml2arff $word

		# now run weka to do machine learning and tag the test data

		bag $word 0.25 2 j48.J48 bag25m2

		# score your results with senseval 2 scoring program
		# note that weka will provide some diagnostic output too

		score-word $word j48.J48.bag25m2  

		# get out of this word directory and move to the next!

		cd ../..
	
	end
end

# duluth2 is not an ensemble based approach. However, we can use
# the ensemble generating program to collect results for all words
# and put them into a single file. Otherwise, the results will remain
# in the individual word files. 

ensembleByDist.pl f0

score bag25m2-f0.j48.J48
