#!/bin/csh

#######################################################################
#This system is identical to duluth6, except that rather than learning
#three Naive Bayesian classifiers from three different feature sets, it
#learns three bagged decision trees from the three feature sets. When
#presented with a test example, each decision tree outputs probabilities
#for each possible sense. These probabilities are summed and the sense
#with the maximum value is assigned to the test example. No information
#from WordNet is utilized by this system. 

#Note that a Naive Bayesian classifier has no "internal" feature selection
#mechanism, and accepts all features provided by the filtering step. The
#decision tree learner performs its own feature selection based on the
#gain ratio, which measures how well a feature partitions the training
#examples into senses. 

#This is the same approach as taken in duluth3 for English. The only
#difference is in the stop list. 
#######################################################################


if ($#argv != 3) then
   echo "duluth8 source-dir stoplist token"
   echo 
   echo "source-dir : directory where data resides"
   echo "in this distribution source-dir is LexSample"
   echo 
   echo "stop-list: text file of stop words"
   echo "in this distribution stop-list is stop.list"
   echo 
   echo "token : text file of token definitions"
   echo "in this distribution token is token1.txt"
   echo 
   echo "run from directory where source-dir, stop-list, and token reside"
   echo
   echo "if you don't want to use stop.list and/or token just create"
   echo "a blank file via echo > dummy and use that instead"
   exit 1
endif   

# specify the name of your stop list and token definition file
# for some reason things work better if you specify the full
# path name of the stoplist and token files

set sourcedir=$1
set stoplist=$PWD/$2
set token=$PWD/$3

if !(-e $sourcedir) then 
	echo "$sourcedir sourcedir does not exit"
	exit 1
endif

if !(-e $stoplist) then 
	echo "$stoplist stoplist does not exit"
	exit 1
endif

if !(-e $token) then 
	echo "$token token does not exit"
	exit 1
endif

# the methods are feature extraction routines that build views of the
# text for the machine learning system weka.

foreach method (f0 g2 f3)

	# the results for each method are contained in a directory,
	# which has the same name as the method

 	if (-e $method) then
                echo $method already exists, aborting
                exit 1
        endif 

	mkdir $method

	# within each method directory, there is a directory for 
	# each word

	# step into source directory and find out the names of
	# all the files to be processed. Each file is named after
        # a word to be processed.

	cd $sourcedir
        set wordlist = (*)
	cd ..

	# now process each of those words

	foreach word ($wordlist)
        
		# move the text for a word into the appropriate directory
             
		cd $sourcedir
		cp -r $word ../$method
		cd ..
		cd $method/$word

		# now process that text with the desired method
		
		$method $word $stoplist $token

		# convert the text into a form that weka likes (arff)

		xml2arff $word

		# now run weka to do machine learning and tag the test data

		bag $word 0.25 2 j48.J48 bag25m2
                                                       
		# score your results with senseval 2 scoring program
		# note that weka will provide some diagnostic output too
		
		score-word $word j48.J48.bag25m2     

		# get out of this word directory and move to the next!

		cd ../..
	
	end
end

# duluth8 is an ensemble of three bagged decision trees,
# where one classifier uses the f0 view of the data, another
# uses the g2 view, and another uses f3. They all get combined
# below based on the distribution    

ensembleByDist.pl f0 g2 f3

score ens-f0g2f3.bag25m2


