#!/bin/csh

#######################################################################
#This system takes a supervised learning approach to word sense
#disambiguation, where a Naive Bayesian classifier is learned from
#sense-tagged training examples. No information from WordNet is utilized
#by this system. 

#The Naive Bayesian classifier is based on a set of features that consists
#of unigrams (one word sequences) that are identified in a filtering set
#prior to learning. These features must meet the following criteria: 

#1) occur 2 or more times and 
#2) are not found on the stop-list. 

#Such unigrams form a set of features. The training examples are converted
#into feature vectors, where each feature represents whether or not a
#unigram occurs in the context of a specific training example. These
#features vectors are used to make the estimates of the parameters of the
#Naive Bayesian classifier. 

#When presented with a test example, the Naive Bayesian classifier will
#output the probability associated with each sense. The sense with the
#highest probability is assigned to the test example. 

#This system implements a standard benchmark, the Naive Bayesian
#classifier based on a bag of words feature set. 

#This is the same approach as taken in duluth4 for English. The only
#differences are in the stop list and the value of the frequency cut off. 
#######################################################################


if ($#argv != 3) then
   echo "duluth9 source-dir stoplist token"
   echo 
   echo "source-dir : directory where data resides"
   echo "in this distribution source-dir is LexSample"
   echo 
   echo "stop-list: text file of stop words"
   echo "in this distribution stop-list is stop.list"
   echo 
   echo "token : text file of token definitions"
   echo "in this distribution token is token1.txt"
   echo 
   echo "run from directory where source-dir, stop-list, and token reside"
   echo
   echo "if you don't want to use stop.list and/or token just create"
   echo "a blank file via echo > dummy and use that instead"
   exit 1
endif   

# specify the name of your stop list and token definition file
# for some reason things work better if you specify the full
# path name of the stoplist and token files

set sourcedir=$1
set stoplist=$PWD/$2
set token=$PWD/$3

if !(-e $sourcedir) then 
	echo "$sourcedir sourcedir does not exit"
	exit 1
endif

if !(-e $stoplist) then 
	echo "$stoplist stoplist does not exit"
	exit 1
endif

if !(-e $token) then 
	echo "$token token does not exit"
	exit 1
endif

# the methods are feature extraction routines that build views of the
# text for the machine learning system weka.

foreach method (f2)

	# the results for each method are contained in a directory,
	# which has the same name as the method

 	if (-e $method) then
                echo $method already exists, aborting
                exit 1
        endif 

	mkdir $method

	# within each method directory, there is a directory for 
	# each word

	# step into source directory and find out the names of
	# all the files to be processed. Each file is named after
        # a word to be processed.

	cd $sourcedir
        set wordlist = (*)
	cd ..

	# now process each of those words

	foreach word ($wordlist)
        
		# move the text for a word into the appropriate directory
             
		cd $sourcedir
		cp -r $word ../$method
		cd ..
		cd $method/$word

		# now process that text with the desired method
		
		$method $word $stoplist $token

		# convert the text into a form that weka likes (arff)

		xml2arff $word

		# now run weka to do machine learning and tag the test data

		wekarun $word NaiveBayes '-o'

		# score your results with senseval 2 scoring program
		# note that weka will provide some diagnostic output too
		
		score-word $word NaiveBayes     

		# get out of this word directory and move to the next!

		cd ../..
	
	end
end

# duluth9 is a single Naive Bayesian classifier, where the
# training data is viewed through the prism of the f2 feature
# set 

ensembleByDist.pl f2

score NaiveBayes-f2


