#!/bin/csh

#######################################################################
#This system takes a supervised learning approach to word sense
#disambiguation, where a decision stump is induced from sense-tagged
#training examples. This system is identical to duluth5, except that it
#relies on a different learning algorithm. Rather than learned a bagged
#decision tree (as duluth5 does) this system simply learns a decision
#stump, a one node decision tree. 

#The features used are the same as duluth5. This system provides a
#baseline that can be used to compare the benefits of learning an entire
#decision tree (duluth5) versus identifying a single node tree (duluthB). 

#This system is motivated by the relative success of decision stumps as
#reported in the NAACL-01 paper "A Decision Tree of Bigrams is an Accurate
#Predictor of Word Sense" by Ted Pedersen. 
#######################################################################


if ($#argv != 3) then
   echo "duluthB source-dir stoplist token"
   echo 
   echo "source-dir : directory where data resides"
   echo "in this distribution source-dir is LexSample"
   echo 
   echo "stop-list: text file of stop words"
   echo "in this distribution stop-list is stop.list"
   echo 
   echo "token : text file of token definitions"
   echo "in this distribution token is token1.txt"
   echo 
   echo "run from directory where source-dir, stop-list, and token reside"
   echo
   echo "if you don't want to use stop.list and/or token just create"
   echo "a blank file via echo > dummy and use that instead"
   exit 1
endif   

# specify the name of your stop list and token definition file
# for some reason things work better if you specify the full
# path name of the stoplist and token files

set sourcedir=$1
set stoplist=$PWD/$2
set token=$PWD/$3

if !(-e $sourcedir) then 
	echo "$sourcedir sourcedir does not exit"
	exit 1
endif

if !(-e $stoplist) then 
	echo "$stoplist stoplist does not exit"
	exit 1
endif

if !(-e $token) then 
	echo "$token token does not exit"
	exit 1
endif
             
# the methods are feature extraction routines that build views of the
# text for the machine learning system weka.

foreach method (f1f3)

	# the results for each method are contained in a directory,
	# which has the same name as the method

	if (-e $method) then
                echo $method already exists, aborting
                exit 1
        endif 

	mkdir $method

	# within each method directory, there is a directory for 
	# each word

	# step into source directory and find out the names of
	# all the files to be processed. Each file is named after
        # a word to be processed.

	cd $sourcedir
        set wordlist = (*)
	cd ..

	# now process each of those words

	foreach word ($wordlist)
        
		# move the text for a word into the appropriate directory

		cd $sourcedir
		cp -r $word ../$method
		cd ..
		cd $method/$word

		# now process that text with the desired method
		
		$method $word $stoplist $token

		# convert the text into a form that weka likes (arff)

		xml2arff $word

		# now run weka to do machine learning and tag the test data

		wekarun $word DecisionStump ' '

		# score your results with senseval 2 scoring program
		# note that weka will provide some diagnostic output too

		score-word $word DecisionStump  

		# get out of this word directory and move to the next!

		cd ../..
	
	end
end

# duluthB is not an ensemble based approach. However, we can use
# the ensemble generating program to collect results for all words
# and put them into a single file. Otherwise, the results will remain
# in the individual word files. 

ensembleByDist.pl f1f3

score DecisionStump
